GNU Flymake

1.1 Starting Flymake

To use Flymake, activate the minor-mode flymake-mode. Use the command flymake-mode to toggle it on and off. The mode line should indicate its presence via an indicator (see Mode line status).

Syntax checks happen “on-the-fly”. Each check is started whenever:

• flymake-mode is started, unless flymake-start-on-flymake-mode is nil;
• the buffer is saved, unless flymake-start-on-save-buffer is nil;
• some changes were made to the buffer more than 0.5 seconds ago (the delay is configurable in flymake-no-changes-timeout).
• When the user invokes the command flymake-start.

If the check detected errors or warnings, the respective buffer regions are highlighted. See Finding diagnostics, for how to learn what the problems are.

1.2 Finding diagnostics

If Flymake has highlighted the buffer, you may hover the mouse on the highlighted regions to learn what the specific problem is. Alternatively, place point on the highlighted regions and use the commands eldoc or display-local-help.

If the diagnostics are outside the visible region of the buffer, flymake-goto-next-error and flymake-goto-prev-error are let you navigate to the next/previous erroneous regions, respectively. It might be a good idea to map them to M-n and M-p in flymake-mode, by adding to your init file:

(define-key flymake-mode-map (kbd "M-n") 'flymake-goto-next-error)
(define-key flymake-mode-map (kbd "M-p") 'flymake-goto-prev-error)

Sometimes it is useful to have a detailed overview of the diagnostics in your files without having to jump to each one. The commands flymake-show-buffer-diagnostics and flymake-show-project-diagnostics are designed to handle this situation. When invoked, they bring up a separate buffer containing a detailed structured listing of multiple diagnostics in the current buffer or for the current project, respectively (see Projects in The Emacs Editor).

The listings is continuously updated as you edit source code, adding or removing lines as you make or correct mistakes. Each line of this listing includes the type of the diagnostic, its line and column in the file, as well as the diagnostic message. You may sort the listing by each of these columns.

1.3 Mode line status

When enabled, Flymake displays its status in the mode line, which provides a visual summary of diagnostic collection. It may also hint at certain exceptional situations encountered when communicating with backends.

The following statuses are defined:

If you would like to customize the appearance of the mode-line, you can use the variables flymake-mode-line-format and flymake-mode-line-counter-format for that purpose. See Customizable variables.

1.4 Troubleshooting

As Flymake supports multiple simultaneously active external backends, is becomes useful to monitor their status. For example, some backends may take longer than others to respond or complete, and some may decide to disable themselves if they are not suitable for the current buffer or encounter some unavoidable problem. A disabled backend is not tried again for future checks of the current buffer.

The commands flymake-reporting-backends, flymake-running-backends and flymake-disabled-backends show the backends currently used and those which are disabled.

Sometimes, re-starting a backend that disabled itself is useful after some external roadblock has been removed (for example after the user installed a needed syntax-check program). Invoking flymake-start with a prefix argument is a way to reset the disabled backend list, so that they will be tried again in the next check. Manually toggling flymake-mode off and on again also works.

Flymake uses a simple logging facility for indicating important points in the control flow. The logging facility sends logging messages to the *Flymake log* buffer. The logged information can be used for resolving various problems related to Flymake. For convenience, a shortcut to this buffer can be found in Flymake’s menu, accessible from the top menu bar or just left of the status indicator. The command flymake-switch-to-log-buffer is another alternative.

Logging output is controlled by the Emacs warning-minimum-log-level and warning-minimum-level variables.

1.5 Customizable variables

This section summarizes customization variables used for the configuration of the Flymake user interface.

flymake-mode-line-lighter ¶

The name of the mode. Defaults to ‘Flymake’.

flymake-mode-line-format ¶

Format to use for the Flymake mode line indicator.

flymake-mode-line-counter-format ¶

mode line construct for formatting Flymake diagnostic counters inside the Flymake mode line indicator.

flymake-no-changes-timeout ¶

If any changes are made to the buffer, syntax check is automatically started after this many seconds, unless the user makes another change, which resets the timer.

flymake-start-on-flymake-mode ¶

A boolean flag indicating whether to start syntax check immediately after enabling flymake-mode.

flymake-start-on-save-buffer ¶

A boolean flag indicating whether to start syntax check after saving the buffer.

flymake-error ¶

A custom face for highlighting regions for which an error has been reported.

flymake-warning ¶

A custom face for highlighting regions for which a warning has been reported.

flymake-note ¶

A custom face for highlighting regions for which a note has been reported.

flymake-error-bitmap ¶

A bitmap used in the fringe to mark lines for which an error has been reported.

flymake-warning-bitmap ¶

A bitmap used in the fringe to mark lines for which a warning has been reported.

flymake-fringe-indicator-position ¶

Which fringe (if any) should show the warning/error bitmaps.

flymake-wrap-around ¶

If non-nil, moving to errors with flymake-goto-next-error and flymake-goto-prev-error wraps around buffer boundaries.

2.1 Customizing Flymake error types

To customize the appearance of error types, the user must set properties on the symbols associated with each diagnostic type.

The three standard diagnostic keyword symbols – :error, :warning and :note – have pre-configured appearances. However a backend may define more (see Backend functions).

The following properties can be set:

• flymake-bitmap, an image displayed in the fringe according to flymake-fringe-indicator-position. The value actually follows the syntax of flymake-error-bitmap (see Customizable variables). It is overridden by any before-string overlay property.
• flymake-overlay-control, an alist ((OVPROP . VALUE) ...) of further properties used to affect the appearance of Flymake annotations. With the exception of category and evaporate, these properties are applied directly to the created overlay (see Overlay Properties in The Emacs Lisp Reference Manual).

  As an example, here’s how to make diagnostics of the type :note stand out more prominently:

  (push '(face . highlight) (get :note 'flymake-overlay-control))
  

  If you push another alist entry in front, it overrides the previous one. So this effectively removes the face from :note diagnostics:

  (push '(face . nil) (get :note 'flymake-overlay-control))
  

  To restore the original look for :note types, empty or remove its flymake-overlay-control property:

  (put :note 'flymake-overlay-control '())
  

• flymake-severity is a non-negative integer specifying the diagnostic’s severity. The higher the value, the more serious is the error. If the overlay property priority is not specified in flymake-overlay-control, flymake-severity is used to set it and help sort overlapping overlays.
• flymake-type-name is a string used to succinctly name the error type, in case the name of the symbol associated with it is very long.
• flymake-category is a symbol whose property list is considered the default for missing values of any other properties.

Three default diagnostic types are predefined: :error, :warning, and :note. By default, each one of them has a flymake-category property whose value is, respectively, the category symbol flymake-error, flymake-warning and flymake-note.

These category symbols’ plist is where the values of customizable variables and faces (such as flymake-error-bitmap) are found. Thus, if you change their plists, Flymake may stop honoring these user customizations.

The flymake-category special property is especially useful for backends which create diagnostics objects with non-default types that differ from an existing type by only a few properties (see Flymake utility functions).

As an example, consider configuring a new diagnostic type :low-priority-note that behaves much like :note, but without an overlay face.

(put :low-priority-note 'flymake-overlay-control '((face . nil)))
(put :low-priority-note 'flymake-category 'flymake-note)

As you might have guessed, Flymake’s annotations are implemented as overlays (see Overlays in The Emacs Lisp Reference Manual). Along with the properties that you specify for the specific type of diagnostic, Flymake adds the property flymake-diagnostic to these overlays, and sets it to the object that the backend created with flymake-make-diagnostic.

Since overlays also support arbitrary keymaps, you can use this along with the functions flymake-diagnostics and flymake-diagnostic-text (see Flymake utility functions) to create interactive annotations, such as in the following example of binding a mouse-3 event (middle mouse button click) to an Internet search for the text of a :warning or :error.

(defun my-search-for-message (event)
  (interactive "e")
  (let* ((diags (flymake-diagnostics (posn-point (event-start event))))
         (topmost-diag (car diags)))
    (eww-browse-url
       (concat
        "https://duckduckgo.com/?q="
        (replace-regexp-in-string
          " " "+" (flymake-diagnostic-text topmost-diag)))
       t)))

(dolist (type '(:warning :error))
  (push '(mouse-face . highlight) (get type 'flymake-overlay-control))
  (push `(keymap . ,(let ((map (make-sparse-keymap)))
                      (define-key map [mouse-2]
                        'my-search-for-message)
                      map))
        (get type 'flymake-overlay-control)))

2.2 Backend functions

Flymake backends are Lisp functions placed in the special hook flymake-diagnostic-functions.

A backend’s responsibility is to diagnose the contents of a buffer for problems, registering the problem’s positions, type, and summary description. This information is collected in the form of diagnostic objects created by the function flymake-make-diagnostic (see Flymake utility functions), and then handed over to Flymake, which proceeds to annotate the buffer.

A request for a buffer check, and the subsequent delivery of diagnostics, are two key events of the interaction between Flymake and backend. Each such event corresponds to a well-defined function calling convention: one for calls made by Flymake into the backend via the backend function, the other in the reverse direction via a callback. To be usable, backends must adhere to both.

The first argument passed to a backend function is always report-fn, a callback function detailed below. Beyond it, functions must be prepared to accept (and possibly ignore) an arbitrary number of keyword-value pairs of the form (:key value :key2 value2...).

Currently, Flymake may pass the following keywords and values to the backend function:

• :recent-changes The value is a list recent changes since the last time the backend function was called for the buffer. If the list is empty, this indicates that no changes have been recorded. If it is the first time that this backend function is called for this activation of flymake-mode, then this argument isn’t provided at all (i.e. it’s not merely nil).

  Each element is in the form (beg end text) where beg and end are buffer positions, and text is a string containing the text contained between those positions (if any), after the change was performed.

• :changes-start and :changes-end The value is, respectively, the minimum and maximum buffer positions touched by the recent changes. These are provided for convenience and only if :recent-changes is also provided.

Whenever Flymake or the user decide to re-check the buffer, backend functions are called as detailed above, and are expected to initiate this check, but aren’t in any way required to complete it before exiting: if the computation involved is expensive, as is often the case with large buffers, that slower task should be scheduled for the future using asynchronous sub-processes (see Asynchronous Processes in The Emacs Lisp reference manual) or other asynchronous mechanisms.

In any case, backend functions are expected to return quickly or signal an error, in which case the backend is disabled (see Troubleshooting).

If the function returns, Flymake considers the backend to be running. If it has not done so already, the backend is expected to call the function report-fn passed to it, at which point Flymake considers the backend to be reporting. Backends call report-fn by passing it a single argument report-action followed by an optional list of keyword-value pairs of the form (:report-key value :report-key2 value2...).

Currently accepted values for report-action are:

• A (possibly empty) list of diagnostic objects created by flymake-make-diagnostic, causing Flymake to annotate the buffer with this information.

  A backend may call report-fn repeatedly in this manner, but only until Flymake considers that the most recently requested buffer check is now obsolete, because, say, buffer contents have changed in the meantime. The backend is only given notice of this via a renewed call to the backend function. Thus, to prevent making obsolete reports and wasting resources, backend functions should first cancel any ongoing processing from previous calls.

• The symbol :panic, signaling that the backend has encountered an exceptional situation and should be disabled.

Currently accepted report-key arguments are:

• :explanation, whose value should give user-readable details of the situation encountered, if any.
• :force, whose value should be a boolean suggesting that Flymake consider the report even if it was somehow unexpected.
• :region, a cons (beg . end) of buffer positions indicating that the report applies to that region and that previous reports targeting other parts of the buffer remain valid.

• Flymake utility functions
• Foreign and list-only diagnostics
• An annotated example backend

;;; ruby-flymake.el --- A ruby Flymake backend  -*- lexical-binding: t; -*-
(require 'cl-lib)
(defvar-local ruby--flymake-proc nil)

(defun ruby-flymake (report-fn &rest _args)
  ;; Not having a ruby interpreter is a serious problem which should cause
  ;; the backend to disable itself, so an error is signaled.
  ;;
  (unless (executable-find
           "ruby") (error "Cannot find a suitable ruby"))
  ;; If a live process launched in an earlier check was found, that
  ;; process is killed.  When that process's sentinel eventually runs,
  ;; it will notice its obsoletion, since it have since reset
  ;; `ruby-flymake-proc' to a different value
  ;;
  (when (process-live-p ruby--flymake-proc)
    (kill-process ruby--flymake-proc))

  ;; Save the current buffer, the narrowing restriction, remove any
  ;; narrowing restriction.
  ;;
  (let ((source (current-buffer)))
    (save-restriction
      (widen)
      ;; Reset the `ruby--flymake-proc' process to a new process
      ;; calling the ruby tool.
      ;;
      (setq
       ruby--flymake-proc
       (make-process
        :name "ruby-flymake" :noquery t :connection-type 'pipe
        ;; Make output go to a temporary buffer.
        ;;
        :buffer (generate-new-buffer " *ruby-flymake*")
        :command '("ruby" "-w" "-c")
        :sentinel
        (lambda (proc _event)
          ;; Check that the process has indeed exited, as it might
          ;; be simply suspended.
          ;;
          (when (memq (process-status proc) '(exit signal))
            (unwind-protect
                ;; Only proceed if `proc' is the same as
                ;; `ruby--flymake-proc', which indicates that
                ;; `proc' is not an obsolete process.
                ;;
                (if (with-current-buffer source (eq proc ruby--flymake-proc))
                    (with-current-buffer (process-buffer proc)
                      (goto-char (point-min))
                      ;; Parse the output buffer for diagnostic's
                      ;; messages and locations, collect them in a list
                      ;; of objects, and call `report-fn'.
                      ;;
                      (cl-loop
                       while (search-forward-regexp
                              "^\\(?:.*.rb\\|-\\):\\([0-9]+\\): \\(.*\\)$"
                              nil t)
                       for msg = (match-string 2)
                       for (beg . end) = (flymake-diag-region
                                          source
                                          (string-to-number (match-string 1)))
                       for type = (if (string-match "^warning" msg)
                                      :warning
                                    :error)
                       when (and beg end)
                       collect (flymake-make-diagnostic source
                                                        beg
                                                        end
                                                        type
                                                        msg)
                       into diags
                       finally (funcall report-fn diags)))
                  (flymake-log :warning "Canceling obsolete check %s"
                               proc))
              ;; Cleanup the temporary buffer used to hold the
              ;; check's output.
              ;;
              (kill-buffer (process-buffer proc)))))))
      ;; Send the buffer contents to the process's stdin, followed by
      ;; an EOF.
      ;;
      (process-send-region ruby--flymake-proc (point-min) (point-max))
      (process-send-eof ruby--flymake-proc))))

(defun ruby-setup-flymake-backend ()
  (add-hook 'flymake-diagnostic-functions 'ruby-flymake nil t))

(add-hook 'ruby-mode-hook 'ruby-setup-flymake-backend)

3.1 Customization variables for the Proc backend

flymake-proc-allowed-file-name-masks ¶

A list of (filename-regexp, init-function, cleanup-function getfname-function) for configuring syntax check tools. See Adding support for a new syntax check tool.

flymake-proc-master-file-dirs ¶

A list of directories for searching a master file. See Locating a master file.

flymake-proc-get-project-include-dirs-function ¶

A function used for obtaining a list of project include dirs (C/C++ specific). See Getting the include directories.

flymake-proc-master-file-count-limit ¶

flymake-proc-check-file-limit ¶

Used when looking for a master file. See Locating a master file.

flymake-proc-err-line-patterns ¶

Patterns for error/warning messages in the form (regexp file-idx line-idx col-idx err-text-idx). See Parsing the output.

flymake-proc-diagnostic-type-pred ¶

A function to classify a diagnostic text as a particular type of error. The value of this variable should be a function taking an error text and returning a diagnostic symbol (see Customizing Flymake error types). If it returns a non-nil value but there is no such symbol in that table, the text is interpreted as a warning. If the function returns nil, the text is assumed to be an error.

The value of this variable can alternatively be a regular expression that should match only warnings.

This variable replaces the old flymake-warning-re and flymake-warning-predicate.

flymake-proc-compilation-prevents-syntax-check ¶

A flag indicating whether compilation and syntax check of the same file cannot be run simultaneously. See Interaction with other modes.

3.2 Adding support for a new syntax check tool

Syntax check tools are configured using the flymake-proc-allowed-file-name-masks list. Each item of this list has the following format:

(filename-regexp, init-function, cleanup-function, getfname-function)

filename-regexp

This field is used as a key for locating init/cleanup/getfname functions for the buffer. Items in flymake-proc-allowed-file-name-masks are searched sequentially. The first item with filename-regexp matching buffer filename is selected. If no match is found, flymake-mode is switched off.

init-function

init-function is required to initialize the syntax check, usually by creating a temporary copy of the buffer contents. The function must return (list cmd-name arg-list). If init-function returns null, syntax check is aborted, but flymake-mode is not switched off.

cleanup-function

cleanup-function is called after the syntax check process is complete and should take care of proper deinitialization, which is usually deleting a temporary copy created by the init-function.

getfname-function

This function is used for translating filenames reported by the syntax check tool into “real” filenames. Filenames reported by the tool will be different from the real ones, as actually the tool works with the temporary copy. In most cases, the default implementation provided by Flymake, flymake-proc-get-real-file-name, can be used as getfname-function.

To add support for a new syntax check tool, write the corresponding init-function and, optionally, cleanup-function and getfname-function. If the format of error messages reported by the new tool is not yet supported by Flymake, add a new entry to the flymake-proc-err-line-patterns list.

The following sections contain some examples of configuring Flymake support for various syntax check tools.

• Example—Configuring a tool called directly
• Example—Configuring a tool called via make

(defun flymake-proc-perl-init ()
  (let* ((temp-file (flymake-proc-init-create-temp-buffer-copy
                     'flymake-proc-create-temp-inplace))
         (local-file (file-relative-name
                      temp-file
                      (file-name-directory buffer-file-name))))
    (list "perl" (list "-wc " local-file))))

(setq flymake-proc-allowed-file-name-masks
      (cons '(".+\\.pl$"
              flymake-proc-perl-init
              flymake-proc-simple-cleanup
              flymake-proc-get-real-file-name)
            flymake-proc-allowed-file-name-masks))

(setq flymake-proc-err-line-patterns
      (cons '("\\(.*\\) at \\([^ \n]+\\) line \\([0-9]+\\)[,.\n]"
              2 3 nil 1)
            flymake-proc-err-line-patterns))

(setq flymake-proc-allowed-file-name-masks
      (cons '(".+\\.c$"
              flymake-proc-simple-make-init
              flymake-proc-simple-cleanup
              flymake-proc-get-real-file-name)
            flymake-proc-allowed-file-name-masks))

(list "make"
      (list "-s" "-C"
            base-dir
            (concat "CHK_SOURCES=" source)
            "SYNTAX_CHECK_MODE=1"
            "check-syntax"))

check-syntax:
	gcc -o /dev/null -S ${CHK_SOURCES} || true

check-syntax:
	$(COMPILE) -o /dev/null -S ${CHK_SOURCES} || true

3.3 Implementation overview

flymake-proc-legacy-flymake saves a copy of the buffer in a temporary file in the buffer’s directory (or in the system temporary directory, for Java files), creates a syntax check command and launches a process with this command. The output is parsed using a list of error message patterns, and error information (file name, line number, type and text) is saved. After the process has finished, Flymake highlights erroneous lines in the buffer using the accumulated error information.

Syntax check is considered possible if there’s an entry in flymake-proc-allowed-file-name-masks matching buffer’s filename and its init-function returns non-nil value.

Two syntax check modes are distinguished:

1. Buffer can be syntax checked in a standalone fashion, that is, the file (its temporary copy, in fact) can be passed over to the compiler to do the syntax check. Examples are C/C++ sources (.c, .cpp) and Java (.java).
2. Buffer can be syntax checked, but additional file, called master file, is required to perform this operation. A master file is a file that includes the current file, so that running a syntax check tool on it will also check syntax in the current file. Examples are C/C++ headers (.h, .hpp).

These modes are handled inside init/cleanup/getfname functions, see Adding support for a new syntax check tool.

The Proc backend contains implementations of all functionality required to support different syntax check modes described above (making temporary copies, finding master files, etc.), as well as some tool-specific (routines for Make, Ant, etc.) code.

3.4 Making a temporary copy

After the possibility of the syntax check has been determined, a temporary copy of the current buffer is made so that the most recent unsaved changes could be seen by the syntax check tool. Making a copy is quite straightforward in a standalone case (mode 1), as it’s just saving buffer contents to a temporary file.

Things get trickier, however, when master file is involved, as it requires to

• locate a master file
• patch it to include the current file using its new (temporary) name.

Locating a master file is discussed in the following section.

Patching just changes all appropriate lines of the master file so that they use the new (temporary) name of the current file. For example, suppose current file name is file.h, the master file is file.cpp, and it includes current file via #include "file.h". Current file’s copy is saved to file file_flymake.h, so the include line must be changed to #include "file_flymake.h". Finally, patched master file is saved to file_flymake_master.cpp, and the last one is passed to the syntax check tool.

3.5 Locating a master file

Master file is located in two steps.

First, a list of possible master files is built. A simple name matching is used to find the files. For a C++ header file.h, the Proc backend searches for all .cpp files in the directories whose relative paths are stored in a customizable variable flymake-proc-master-file-dirs, which usually contains something like ("." "./src"). No more than flymake-proc-master-file-count-limit entries is added to the master file list. The list is then sorted to move files with names file.cpp to the top.

Next, each master file in a list is checked to contain the appropriate include directives. No more than flymake-proc-check-file-limit of each file are parsed.

For file.h, the include directives to look for are #include "file.h", #include "../file.h", etc. Each include is checked against a list of include directories (see Getting the include directories) to be sure it points to the correct file.h.

First matching master file found stops the search. The master file is then patched and saved to disk. In case no master file is found, syntax check is aborted, and corresponding status (‘!’) is reported in the mode line. See Mode line status.

3.6 Getting the include directories

Two sets of include directories are distinguished: system include directories and project include directories. The former is just the contents of the INCLUDE environment variable. The latter is not so easy to obtain, and the way it can be obtained can vary greatly for different projects. Therefore, a customizable variable flymake-proc-get-project-include-dirs-function is used to provide the way to implement the desired behavior.

The default implementation, flymake-proc-get-project-include-dirs-imp, uses a make call. This requires a correct base directory, that is, a directory containing a correct Makefile, to be determined.

As obtaining the project include directories might be a costly operation, its return value is cached in the hash table. The cache is cleared in the beginning of every syntax check attempt.

3.7 Locating the buildfile

The Proc backend can be configured to use different tools for performing syntax checks. For example, it can use direct compiler call to syntax check a perl script or a call to make for a more complicated case of a C/C++ source. The general idea is that simple files, like Perl scripts and HTML pages, can be checked by directly invoking a corresponding tool. Files that are usually more complex and generally used as part of larger projects, might require non-trivial options to be passed to the syntax check tool, like include directories for C++. The latter files are syntax checked using some build tool, like Make or Ant.

All Make configuration data is usually stored in a file called Makefile. To allow for future extensions, Flymake uses a notion of buildfile to reference the project configuration file.

Special function, flymake-proc-find-buildfile is provided for locating buildfiles. Searching for a buildfile is done in a manner similar to that of searching for possible master files. In case there’s no build file, the syntax check is aborted.

Buildfile values are also cached.

3.8 Starting the syntax check process

The command line (command name and the list of arguments) for launching a process is returned by the initialization function. The Proc backend then just starts an asynchronous process and configures a process filter and sentinel, which are used for processing the output of the syntax check tool. When exiting Emacs, running processes will be killed without prompting the user.

3.9 Parsing the output

The output generated by the syntax check tool is parsed in the process filter/sentinel using the error message patterns stored in the flymake-proc-err-line-patterns variable. This variable contains a list of items of the form (regexp file-idx line-idx err-text-idx), used to determine whether a particular line is an error message and extract file name, line number and error text, respectively. Error type (error/warning) is also guessed by matching error text with the ‘^[wW]arning’ pattern. Anything that was not classified as a warning is considered an error. Type is then used to sort error menu items, which shows error messages first.

The Proc backend is also able to interpret error message patterns missing err-text-idx information. This is done by merely taking the rest of the matched line ((substring line (match-end 0))) as error text. This trick allows making use of a huge collection of error message line patterns from compile.el. All these error patterns are appended to the end of flymake-proc-err-line-patterns.

The error information obtained is saved in a buffer local variable. The buffer for which the process output belongs is determined from the process-id->buffer mapping updated after every process launch/exit.

3.10 Interaction with other modes

The only mode the Proc backend currently knows about is compile.

The Proc backend can be configured to not start syntax check if it thinks the compilation is in progress, by testing the compilation-in-progress variable. The reason why this might be useful is saving CPU time in case both syntax check and compilation are very CPU intensive. The original reason for adding this feature, though, was working around a locking problem with MS Visual C++ compiler. The variable in question is flymake-proc-compilation-prevents-syntax-check.

The Proc backend also provides an alternative command for starting compilation, flymake-proc-compile. It just kills all the active syntax check processes before calling compile.